nix-config/nixosModules/dev/docker.nix

{
  config,
  lib,
  ...
}:
let
  cfg = config.krop.docker;
in
{
  options.krop.docker = {
    enable = lib.mkOption {
      type = lib.types.bool;
      default = false;
      example = true;
      description = "Whether to enable Docker service.";
    };
    addUserToGroup = lib.mkOption {
      type = lib.types.bool;
      default = true;
      example = false;
      description = "Whether to add the user to the Docker group.";
    };
    changeDefaultNetwork = lib.mkOption {
      type = lib.types.bool;
      default = false;
      example = true;
      description = "Whether to change docker daemon to use different networks.";
    };
  };

  config = lib.mkIf cfg.enable {
    virtualisation.docker = {
      enable = true;
      daemon.settings = lib.mkIf cfg.changeDefaultNetwork {
        default-address-pools = [
          {
            base = "10.250.0.0/16";
            size = 24;
          }
        ];
      };
    };
    users.users.krop = lib.mkIf cfg.addUserToGroup {
      extraGroups = [ "docker" ];
    };
  };
}