{
  config,
  lib,
  pkgs,
  ...
}:
let
  cfg = config.krop;
  docker-cfg = {
    enable = lib.mkEnableOption "Whether to enable Docker.";
    addUserToGroup = lib.mkOption {
      type = lib.types.bool;
      default = true;
      example = false;
      description = "Whether to add the user to the Docker group.";
    };
    changeDefaultNetwork = lib.mkOption {
      type = lib.types.bool;
      default = false;
      example = true;
      description = "Whether to change docker daemon to use different networks.";
    };
  };
  podman-cfg = {
    enable = lib.mkEnableOption "Whether to enable Podman.";
  };
  waydroid-cfg = {
    enable = lib.mkEnableOption "Whence to enable Waydroid.";
  };
in
{
  options.krop = {
    docker = docker-cfg;
    podman = podman-cfg;
    waydroid = waydroid-cfg;
  };

  config = {
    virtualisation.docker = lib.mkIf cfg.docker.enable {
      enable = true;
      daemon.settings = lib.mkIf cfg.docker.changeDefaultNetwork {
        default-address-pools = [
          {
            base = "10.250.0.0/16";
            size = 24;
          }
        ];
      };
    };

    virtualisation.podman = lib.mkIf cfg.podman.enable {
      enable = true;
    };

    environment.systemPackages = lib.mkIf cfg.podman.enable [
      pkgs.buildah
    ];

    virtualisation.waydroid.enable = cfg.waydroid.enable;

    users.users.krop = lib.mkIf (cfg.docker.addUserToGroup && cfg.docker.enable) {
      extraGroups = [ "docker" ];
    };
  };
}